Skript file: /~heha/hs/dos/dosmisc.zip/START.BAT

@echo off
if "%1"=="@@" goto @@
rem Nachbau des Windows9x-Kommandos "start" - INKLUSIVE /wait
rem Benötigt eine Umgebungsvariable "TEMP", das Programm CHOICE.COM
rem sowie ein laufendes Windows-Programm "STARTRUN"
rem V.1.02 h#s 09/02

rem rekursiver Aufruf der BATCH ermöglicht Platz für temporäre(!)
rem Umgebungsvariablen auch aus Shells wie Volkov oder Norton Commander
%comspec% /e:1024 /c %0 @@ %1 %2 %3 %4 %5 %6
goto exi

:@@
set ini=%TEMP%\START.TMP
set wait=0
:r
set show=1
:paramloop
shift
if "%1"=="" goto usage
if "%1"=="/m" goto min
if "%1"=="/minimized" goto min
if "%1"=="/max" goto max
if "%1"=="/maximized" goto max
if "%1"=="/r" goto r
if "%1"=="/restored" goto r
if "%1"=="/hidden" goto hide
if "%1"=="/show" goto show
if "%1"=="/w" goto wait
if "%1"=="/wait" goto wait
goto run

:min
set show=7
goto paramloop

:max
set show=3
goto paramloop

:hide
set show=0
goto paramloop

:show
shift
set show=%1
goto paramloop

:wait
set wait=1
goto paramloop


:usage
echo Startet Windows-Programm oder DOS-Box; STARTRUN.EXE muss dazu laufen!
echo Parameter:	/m /minimized
echo 		/max /maximized
echo 		/r /restored
echo 	extra:	/hidden
echo 	extra:	/show n
echo 		/w /wait
goto exi

:run
echo %show%>>%ini%
echo %wait%>>%ini%
cd>>%ini%
echo %1>>%ini%
if not "%2"=="" echo %2 %3 %4 %5>>%ini%
ren %ini% START.RUN
:waitloop
rem nachfolgendes DELAY mit Tastenabfrage gibt System-VM eine Chance zum Laufen
choice /c:n /t:n,1 >nul
if exist %temp%\START.RUN goto waitloop
:exi