fini
/CLEAR,START
!
!#######################################################################
!#                                                                     #
!#    Balken mit Längsbelastung                                        #
!#                                                                     #
!#    Nichtlineare Beulanalyse                                         #
!#                                                                     #
!#    (automatische Schrittweitensteuerung)                            #
!#                                                                     #
!#######################################################################
!
!
/filnam,nlfem7-2
/title,nichtlineare Beulanalyse mit automatischer Schrittweitensteuerung
!Preprozessing
/prep7

/prep7
!
!Elemententyp: BEAM3
et,1,beam3

! Materialdaten
! Hooke
MP,EX,1,210000
MP,PRXY,1,.3

! Querschnittsdaten
length = 1000
! Fläche, Flaechenträgheitsmoment, Dicke
r,1,100,833,10

! Geometrie
k,1,0,0
k,2,0,length
l,1,2
lesize,all,,,10	! Anzahl der zu verwendenen Elemente
lmesh,all

fini

! Lösungsteil
/solu
!Randbedingungen
nsel, s,loc,y,0
d,all,all
node_1=ndnext(0)  ! speichert die Nummer des Knotens

! Belastung oberhalb der Knicklast
nsel, s,loc,y,length
f,all,fy,-500
f,all,fx, 1 ! Kleine Störung
node_2=ndnext(0)  ! speichert die Nummer des Knotens

nsel,all

! Grosse Verformungen
nlgeom,on

! Unterteilt in 20 Unterschritte
nsubst,20,,20
neqit,100
! automatische Schrittweitensteuerung
autots,on

outres,all,all  ! alle Ergebnisse abspeichern
solve


! Darstellung der Verschiebung
/post26
nsol,2,node_2,u,x       ! Speichert die Verschiebung ueber der Zeit auf Feld 2
rforce,3,node_1,f,y     ! Speichert die Reaktionskraft ueber der Zeit auf Feld 3
xvar,3
plvar,2


