fini
/CLEAR,START
!
!#######################################################################
!#                                                                     #
!#    Balken mit Längsbelastung                                        #
!#                                                                     #
!#    Knickanalyse - Eigenwertberechnung                               #
!#                                                                     #
!#######################################################################
!
!
/filnam,nlfem7-1
/title, Eigenwertanalyse
/prep7
!
!Elemententyp: BEAM3
et,1,beam3

! Materialdaten
! Hooke
MP,EX,1,210000
MP,PRXY,1,.3

! Querschnittsdaten
length = 1000
! Fläche, Flaechenträgheitsmoment, Dicke
r,1,100,833,10

! Geometrie
k,1,0,0
k,2,0,length
l,1,2
lesize,all,,,10	! Anzahl der zu verwendenen Elemente
lmesh,all

fini

! Lösungsteil
/solu
!Randbedingungen
nsel, s,loc,y,0
d,all,all
nsel, s,loc,y,length

! Einheitslast (die Last wird vom Programm skaliert)
f,all,fy,-1
nsel,all

! Lösen des statischen Problems
! Berücksichtigung von prestress-Effekten
! -> Berechnung der geometrischen Steifigkeitsmatrix als Vorbereitung für die Beulanalyse
pstres,on 
solve

fini
/solu
! Buckling-Eigenwertanalyse
antype,buck
! Spezifiziert Analysemethode (Subspace Iteration)
! alternativ: Block Lanczos
bucopt,subs,1

!Anzahl der zu expandierenden Modes (Beulformen)
mxpand,1
solve

!Eigenwerte im Out-Window
!Postprozessing
/post1
set,1,1
pldisp,1