fini
/CLEAR,START
!
!#######################################################################
!#                                                                     #
!#    Ringstauchversuch                                                #
!#                                                                     #
!#    Kontaktanalyse mit Reibung                                       #
!#                                                                     #
!#######################################################################
!
!
/filnam,nlfem7-2
/title, Ringstauchversuch
!Preprozessing
/prep7

!Elementtypen: Plane42, rotationssymmetrisches Problem
et,1,plane42,,,1

!Kontaktelement:CONTA171 (2D)
!KEYOPT(2)= 0 - augmented Lagrange (default)
!KEYOPT(2)= 1 - Penalty
!KEYOPT(2)= 2 - MPC
!KEYOPT(2)= 3 - Lagrange (normal) - Penalty (tangent)
!KEYOPT(2)= 4 - pure Lagrange
et,2,conta171,,4,,1
!Targetelement:TARGE169 (2D)
et,3,targe169
!Realkonstanten fuer Zuordnung der Kontaktpartner
r,2

! Materialdaten
! Hooke
MP,EX,1,10
MP,PRXY,1,.48

! Die Kontaktelemente erhalten eigenen Materialparametersatz
! Reibkoeffizienten
mp,mu,2,0.1

!Geometrie

! Hoehe und Radius
height = 10
radius = 10
x_offset = 5

! Anzahl der Elemente in Hoehenrichtung und radialer Richtung
h_nr_elems = 10
r_nr_elems = 10 

! Eckpunkte des Gesamtbereichs anlegen
k,1,x_offset,0,0
k,2,x_offset+radius,0,0
k,3,x_offset+radius,height
k,4,x_offset,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,r_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,x_offset			! linke Kante
lsel,a,loc,x,x_offset+radius		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung
lsel,all

! Vernetzen
amap,1,1,2,3,4 

! Stempel (rigid - starr)
gap=1
k,5,0,height+gap
k,6,25,height+gap
l,5,6

! Vernetzung Kontakt
! CONTA171-Elemente auswählen
! Diese werden auf den stark deformierten Körper aufgebracht (Werkstück, Probe)
type,2  
real,2
mat,2
lsel,s, loc,y,height
lmesh,all

! TARGE169-Elemente auswählen
! Diese werden auf den wenig deformierten/starren Körper aufgebracht (Werkzeug)
type,3
real,2
mat,2
lsel,s, loc,y,height+gap
lmesh,all


! Kontrolle Orientierung der Elementkoordinatensysteme
! Die Normalen der Kontaktelemente muessen einander zugerichtet sein
/psymb,esys,1
esel,s,type,,2
eplot
esel,all
esel,s,type,,3
eplot
esel,all

ksel,s,kp,,3        ! selektiert Keypoint 3
nslk                ! selektiert den Knoten auf dem Keypoint
node_kp3=ndnext(0)  ! speichert die Nummer des Knotens

fini
!*************************** Loesungsteil ***************************
/solu
!Große Verformungen
nlgeom,on
! Unterteilt in 40 Unterschritte
nsubst,40,40,40
outres,all,all  ! alle Ergebnisse abspeichern

!Randbedingungen
!Symmetrierandbedingung
nsel,s,loc,y,0
d,all,uy
nsel,all

!Stempelbewegung
nsel,s,loc,y,height+gap
d,all,uy,-(2.5+gap)
nsel,all
solve
fini

!*************************** Postprocessing ***************************

/post1
/dscale,,1
pldisp,2

/post26
nsol,2,node_kp3,u,x     ! Speichert die Verschiebung ueber der Zeit auf Feld 3
plvar,2

fini
