fini
/CLEAR,START
!#########################################################################
!#                                                                       #
!#    Biegung eines Kragträgers                                          #
!#                                                                       #
!#    Lineares Stoffgesetz,                                              #
!#    Untersuchung zum Einfluss großer Deformation                       #
!#                                                                       #
!#########################################################################
!
!

/PREP7 


!*************************** Modellierung ***************************
! Materialdaten
! Hooke
MP,EX,1,10
MP,PRXY,1,.48

! Neo-Hooke
!TB,hyper,,,,NEO
!TBDATA,,3.378,0.024

! Elementtyp: 8-Knoten Viereck
et,1,plane183
! Ebener Spannungszustand mit Dicke
keyopt,1,3,3
! Dicke auf 5 setzen
R,1,5

! Belastung
force=0.5

! Hoehe und Breite
height = 5
width = 40

! Anzahl der Elemente in Hoehenrichtung und radialer Richtung
h_nr_elems = 5
w_nr_elems = 10 

! Eckpunkte des Gesamtbereichs anlegen
k,1,0,0,0
k,2,width,0,0
k,3,width,height
k,4,0,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,w_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,0			! linke Kante
lsel,a,loc,x,width		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung

! Vernetzen
amap,1,1,2,3,4 
fini

!*************************** Loesungsteil ***************************

/solu
! Randbedingungen anlegen
nsel,s,loc,x,0		! linke Kante
d,all,ux,0 		    ! ux = 0
d,all,uy,0 		    ! uy = 0

! Strategie 1 fuer die Belastung: Knotenkraefte
nsel,s,loc,x,width	    ! letzter Knoten am oberen Rand
nsel,r,loc,y,height
f,all,fy, -force/6 

nsel,s,loc,x,width*0.95	    ! vorletzter Knoten am oberen Rand
nsel,r,loc,y,height
f,all,fy, -2*force/3 

nsel,s,loc,x,width*0.90	    ! drittletzter Knoten am oberen Rand
nsel,r,loc,y,height
f,all,fy, -force/6 

! Strategie 2 fuer die Belastung: Linienlast
!lsel,s,loc,y,height	! obere kante
!lsel,r,loc,x,width*0.90,width
!sfl,all,pres,-force/(width*0.1)

! Grosse Verformungen
nlgeom,on

allsel

solve

/post1
! Anzeigen des verformten Körpers und der unverformten Kontur
/dscale,,1
pldisp,2

fini


