fini
/CLEAR,START
!#########################################################################
!#                                                                       #
!#    Simulation eines Zugversuchs mit einem Kunststoffstab              #
!#                                                                       #
!#    Hyperelastisches Stoffgesetz,                                      #
!#    Untersuchung zum Einfluss großer Deformation                       #
!#                                                                       #
!#########################################################################
!
!

/PREP7 


!*************************** Modellierung ***************************
! Materialdaten
! Hooke
MP,EX,1,10
MP,PRXY,1,.48

! Neo-Hooke
!TB,hyper,,,,NEO
!TBDATA,,3.378,0.024

! Elementtyp: 8-Knoten Viereck
et,1,plane183
!Ebener Spannungszustand mit Dicke
keyopt,1,3,3
! Dicke auf 5 setzen
R,1,5

! Ebener Verzerrungszustand
!keyopt,1,3,2

! prozentuale Deformation
defo=0.5

! Hoehe und Breite
height = 5
width = 40

! Verschiebung der unteren Kante
shear = 5

! Anzahl der Elemente in Hoehenrichtung und radialer Richtung
h_nr_elems = 5
w_nr_elems = 10 

! Eckpunkte des Gesamtbereichs anlegen
k,1,0,0,0
k,2,width,0,0
k,3,width,height
k,4,0,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,w_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,0			! linke Kante
lsel,a,loc,x,width		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung

! Vernetzen
amap,1,1,2,3,4 
fini

!*************************** Loesungsteil ***************************

/solu
! Randbedingungen anlegen
nsel,s,loc,x,0		! linke Kante
d,all,ux,0 		    ! ux = 0
nsel,r,loc,y,0		! ein Knoten außerdem in y-Richtung festhalten
d,all,uy,0 		    ! ux = 0

nsel,s,loc,x,width	    ! rechte kante
cp,2,ux,all             ! Verschiebung in x-Richtung koppeln

node_1=ndnext(0)  ! speichert die Nummer des ersten Knotens
d,node_1,ux, width*defo

! Grosse Verformungen
nlgeom,on

!Anforderungen an Post-Ausgabe
outres,all,all  ! alle Ergebnisse abspeichern

time,1
! Unterteilt in 20 Unterschritte
nsubst,20,20,20

allsel

solve
fini

!*************************** Postprocessing ***************************
/post1
! Anzeigen des verformten Körpers und der unverformten Kontur
/dscale,,1
pldisp,2

/post26
nsol,2,node_1,u,x       ! Speichert die Verschiebung ueber der Zeit auf Feld 2
rforce,3,node_1,f,x     ! Speichert die Reaktionskraft ueber der Zeit auf Feld 3
ansol,4,node_1,EPEL,X,exx  ! Speichert die Verzerrungen ueber der Zeit auf Feld 4
ansol,5,node_1,S,X,sxx     ! Speichert die Spannung ueber der Zeit auf Feld 5

! Darstellung der Reaktionkraft ueber der Verschiebung
xvar,2
plvar,3

! Darstellung der Verzerrung ueber der Verschiebung
xvar,2
plvar,4

! Darstellung der Spannung ueber der Verzerrung

xvar,4
plvar,5

! Darstellung der Reaktionskraft ueber der Spannung
xvar,5
plvar,3


