fini
/CLEAR,START
!#########################################################################
!#                                                                       #
!#    Simulation eines Kriechversuchs mit einem Kunststoffzylinder  #
!#                                                                       #
!#    viskoelastisches Stoffgesetz,                                      #
!#    Neo-Hooke für die elastischen Komponenten                          #
!#                                                                       #
!#########################################################################
!
!

/PREP7 


!*************************** Modellierung ***************************
! Materialdaten
! E-Modul und Querkontraktionszahl

! Neo-Hooke
TB,hyper,,,,NEO
TBDATA,,3.378,0.016

tb,prony,1,,1,shear	!define viscosity parameters
tbdata,1,1,2
tb,prony,1,,1,bulk	!define viscosity parameters
tbdata,1,1,2

! externe Kraft
force = 500

! Hoehe und Radius
height = 40
radius = 10

! Anzahl der Elemente in Hoehenrichtung und radialer Richtung
h_nr_elems = 20
r_nr_elems = 10 

! Elementtyp: 8-Knoten Viereck
et,1,plane183
! Axial-symmetrisch
keyopt,1,3,1

! Eckpunkte des Gesamtbereichs anlegen
k,1,0,0,0
k,2,radius,0,0
k,3,radius,height
k,4,0,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,r_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,0			! linke Kante
lsel,a,loc,x,radius		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung

! Vernetzen
amap,1,1,2,3,4 

!*************************** Loesungsteil ***************************

/solu
! Randbedingungen anlegen
nsel,s,loc,y,0		! untere Kante
d,all,ux,0 		    ! ux = 0
d,all,uy,0 		    ! ux = 0

nsel,s,loc,y,height	    ! obere kante
d,all,ux,0 		        ! ux = 0
cp,2,uy,all             ! Verschiebung in y-Richtung koppeln

ksel,s,kp,,3        ! selektiert Keypoint 3
nslk                ! selektiert den Knoten auf dem Keypoint
node_kp3=ndnext(0)  ! speichert die Nummer des Knotens

! Die Kraft wird nur auf den einen Knoten aufgebracht,
! durch die Koppelung verteilt sich die Kraft auf dem Rand
nsel,s,node,,node_kp3
f,all,fy, force

! Grosse Verformungen
nlgeom,on

!Anforderungen an Post-Ausgabe
outres,all,all  ! alle Ergebnisse abspeichern

allsel

!Lastfall 1: Anfangszustand
time,1e-4
solve

!Lastfall 2: Haltephase
time,10
! Unterteilt in 20 Unterschritte
nsubst,20,20,20
solve
fini

!*************************** Postprocessing ***************************
/post1
! Anzeigen des verformten Körpers und der unverformten Kontur
/dscale,,1
pldisp,2

/post26
nsol,2,node_kp3,u,y     ! Speichert die Verschiebung ueber der Zeit auf Feld 3
plvar,2

fini

