fini
/CLEAR,START
!#######################################################################
!#                                                                     #
!#    Schubversuch - einfacher Schub                                   #
!#                                                                     #
!#    elastisch-plastisches Materialverhalten                          #
!#    (bilinear kinematische Verfestigung)                             #
!#                                                                     #
!#######################################################################

/PREP7 

/title, Schubversuch - einfacher Schub (bkin)

!*************************** Modellierung ***************************
! Materialdaten
! E-Modul und Querkontraktionszahl
mp,ex,1,210000
mp,prxy,1,0.3

! bilinear isotrope Verfestigung
!tb,biso
! bilinear kinematische Verfestigung
tb,bkin
!Fliessgrenze,Tangentenmodul
tbdat,1,500,10000

et,1,plane183,,,2

! Hoehe und Breite
height = 40
width = 40

! Verschiebung der unteren Kante
shear = 1

! Anzahl der Elemente in Hoehenrichtung und radialer Richtung
h_nr_elems = 10
w_nr_elems = 10 

! Eckpunkte des Gesamtbereichs anlegen
k,1,0,0,0
k,2,width,0,0
k,3,width,height
k,4,0,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,w_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,0			! linke Kante
lsel,a,loc,x,width		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung

! Vernetzen
amap,1,1,2,3,4 
fini

!
!*************************** Loesungsteil ***************************
/solu
!Lastschrittsteuerung
nlgeom,on
outres,all,all  ! alle Ergebnisse abspeichern

!
!********** 1. Lastschritt *********
!
TIME,1           	! Zeit am Ende des Lastschritts
!Festhalten untere Kante 
nsel,s,loc,y,0
d,all,ux,0
d,all,uy,0
nsel,all

!Fixierung obere Kante in y-Richtung und Verschiebung in x-Richtung
nsel,s,loc,y,height
d,all,uy
!d,all,ux,shear
cp,1,ux,all         ! Verschiebung in x-Richtung koppeln
node_cp1=ndnext(0)  ! Der Stellvertreterknoten dieses Sets
allsel 

d,node_cp1, ux, shear

nsel,all
KBC,0         		! lineare Interpolation der Belastung
nsubst,25,25,25
LSWRITE

!
!********** 2. Lastschritt *********
!
TIME,3           	! Zeit am Ende des Lastschritts

d,node_cp1, ux, -shear

nsel,all
KBC,0         		! lineare Interpolation der Belastung
nsubst,25,25,25
LSWRITE

!
!********** 3. Lastschritt *********
!
TIME,5           	! Zeit am Ende des Lastschritts

d,node_cp1, ux, shear

nsel,all
KBC,0         		! lineare Interpolation der Belastung
nsubst,25,25,25
LSWRITE

! Loesung
LSSOLVE,1,3,1
fini

/post26
numvar,200
! Die Spannungen auszurechnen bringt keine sinnvollen Ergebnisse mehr
nsol,2,node_cp1,U,X,ux_2          ! Speichert die Verschiebung ueber der Zeit auf Feld 2
rfor,3,node_cp1,f,x,fx_3          ! Speichert die Reaktionskraft ueber der Zeit auf Feld 3

! Skalieren der um Spannung und Verzerrung zu Erhalten
filldata,198,,,,height,0
quot,4,2,198,,exy_4

filldata,199,,,,width,0
quot,5,3,199,,sxy_5


!Anzeige der Schubspannung ueber der Schubverzerrung
/axlab,x,strain
/axlab,y,stress
xvar,4
plvar,5

fini
