fini
/CLEAR,START
!#######################################################################
!#                                                                     #
!#    Simulation eines Druckversuchs mit einem Gummizylinder           #
!#                                                                     #
!#    Vergleich lineares Materialverhalten                             #
!#    ohne und mit großen Deformationen                                #
!#                                                                     #
!#######################################################################
!
!

/PREP7 


!*************************** Modellierung ***************************
! Materialdaten
! E-Modul und Querkontraktionszahl
MP,EX,1,10
MP,PRXY,1,.48

! prozentuale Deformation
defo=-0.3

! Hoehe und Radius
height = 40
radius = 10

! Anzahl der Elemente in Hoehenrichtung und radialer Richtung
h_nr_elems = 20
r_nr_elems = 10 

! Elementtyp: 8-Knoten Viereck
et,1,plane183
! Axial-symmetrisch
keyopt,1,3,1

! Eckpunkte des Gesamtbereichs anlegen
k,1,0,0,0
k,2,radius,0,0
k,3,radius,height
k,4,0,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,r_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,0			! linke Kante
lsel,a,loc,x,radius		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung

! Vernetzen
amap,1,1,2,3,4 

!*************************** Loesungsteil ***************************

/solu
! Randbedingungen anlegen
nsel,s,loc,y,0		! untere Kante
d,all,ux,0 		    ! ux = 0
cp,1,uy,all         ! Verschiebung in y-Richtung koppeln
! bei gekoppelten Freiheitsgraden darf nur noch am Knoten mit der kleinsten
! Nummer eine Verschiebungsrandbedingung aufgebracht werden
nsel,r,loc,x,0
d,all,uy, 0

nsel,s,loc,y,height	    ! obere kante
d,all,ux,0 		        ! ux = 0
cp,2,uy,all             ! Verschiebung in y-Richtung koppeln

ksel,s,kp,,3        ! selektiert Keypoint 3
nslk                ! selektiert den Knoten auf dem Keypoint
node_kp3=ndnext(0)  ! speichert die Nummer des Knotens

! Die Verschiebung wird nur auf den einen Knoten aufgebracht,
! die restlichen Knoten sind gekoppelt
nsel,s,node,,node_kp3
d,all,uy, defo*height

! Grosse Verformungen
! nlgeom,on
! Unterteilt in 20 Unterschritte
nsubst,20,20,20

!Anforderungen an Post-Ausgabe
outres,nsol,1
outres,rsol,1

allsel
solve
fini

!*************************** Postprocessing ***************************
/post1
! Anzeigen des verformten Körpers und der unverformten Kontur
/dscale,,1
pldisp,2


/post26
!Nutzung der Iterationsnummer als Zeitvariable
tvar,1                  ! Zeit wird als Laufvariable verwendet
nsol,3,node_kp3,u,y     ! Speichert die Verschiebung ueber der Zeit auf Feld 3
rfor,4,node_kp3,f,y     ! Speichert die Reaktionskraft ueber der Zeit auf Feld 4
xvar,3                  ! Verwendet Feld 3 als x-Achse
plvar,4                 ! Stellt Feld 4 dar
fini
