 FINISH  
/CLEAR,NOSTART  

!#######################################################################
!#                                                                     #
!#    FEM II, Beispiel 1                                               #
!#    Ein lineares Problem, ebener Spannunszustand                     #
!#    gleichmaessige Belastung am Rand                                 #
!#    Last realisiert als Linienlast                                   #
!#                                                                     #
!#######################################################################

/PREP7 
MPTEMP,,,,,,,,  
MPTEMP,1,0  

!*************************** Modellierung ***************************
! Materialdaten
! E-Modul und Querkontraktionszahl
MPDATA,EX,1,,210000 
MPDATA,PRXY,1,,.3

! Hoehe und Breite
height = 40
width = 10

! Anzahl der Elemente in Hoehen und Breitenrichtung
h_nr_elems = 6
b_nr_elems = 3 

! Elementtyp
et,1,plane42

! Eckpunkte des Gesamtbereichs anlegen
k,1,0,0,0
k,2,width,0,0
k,3,width,height
k,4,0,height

! Definition der Flaeche
a,1,2,3,4

! Definition der Anzahl Elemente die an den Kanten verwenden werden sollen
lsel,s,loc,y,0      	! untere Kante
lsel,a,loc,y,height		! und obere kante
lesize,all,,,b_nr_elems	! Anzahl der zu verwendenen Elemente in Breitenrichtung
lsel,s,loc,x,0			! linke Kante
lsel,a,loc,x,width		! und rechte Kante
lesize,all,,,h_nr_elems	! Anzahl der zu verwendenen Elemente in Hoehenrichtung

! Vernetzen
amap,1,1,2,3,4 

!*************************** Loesungsteil ***************************

/solu
! Randbedingungen anlegen
nsel,s,loc,y,0		! untere Kante
d,all,all,0 		! ux = 0, uy = 0

force = 100         ! Gesamtkraft in N
lsel,s,loc,y,height	! obere kante
! Kraftrandbedingung als Linienlast
! negatives Vorzeichen, da der Druck senkrecht auf das Element wirkend angenommen wird
sfl,all,pres,-force/width

allsel
! Loesung 
solve
fini

!*************************** Postprocessing ***************************
/post1
! Anzeigen des verformten Körpers und der unverformten Kontur
pldisp,2
!Anzeige der Spannungen in x-Richtung (nodal solution)
plnsol,s,x
!Anzeige der Spannungen in y-Richtung (nodal solution)
plnsol,s,y
fini


