list	p=16f84,r=dec
	include	"p16f84.inc"
	include	"mymacros.inc"
	__idlocs 1099h
	__config _XT_OSC & _WDT_OFF & _PWRTE_ON
;#define SIMULATE
#define DEBUG
BANKSEL macro arg
#if (arg)
	bsf	STATUS,5
#else
	bcf	STATUS,5
#endif
	endm

;****************
;** Konstanten **
;****************
PHASE180  equ	10000/64	;=156 (abgerundet) - bezieht sich auf 50 Hz
TIMEOVER  equ	11000/64	;=171 (Netzausfall) - bezieht sich auf 50 Hz
PHASEADD  equ	PHASE180/39	;Günstige Teiler sind 2,3,4,6,12,13,39,...
WAITRELAY equ	100/10		;100 ms
;Primfaktoren von 156 sind 2*2*3*13

;Belegung PortA
TRIAC	equ	0	;Bit0	Triac-Steuerausgang, 0=EIN
RELAY	equ	2	;Bit2	Relais-Steuerausgang, 0=EIN
TESTA	equ	3	;Bit3	Testausgang REMA

;Belegung PortB
SWON	equ	4	;Bit4	Schalter-Eingang, 0=EIN
SWLEARN	equ	5	;Bit5	Lern-Taster, 0=EIN
ZERO_I	equ	6	;Bit6	Nulldurchgangs-Detektor für Strom
ZERO_U	equ	7	;Bit7	Nulldurchgangs-Detektor für Spannung

;Im Unterschied zu den Vorgängerversionen arbeitet dieses Programm
;mit der Methode, die Datenverarbeitung (Tastenabfrage u.ä.)
;je nach Zündzeitpunkt (kleiner oder größer 5ms = Viertelperiode)
;vor oder nach dem Zündvorgang durchzuführen
;Hier keine Interruptsteuerung, um Portierung zu kleineren PICs
;(z.B. 8-pin PIC12CE673) zu ermöglichen

;************************
;** RAM-Speicherzellen **
;************************
PHASE	equ	10h		;speichert momentanen Zündwinkel
LASTIN	equ	11h		;letzter IN-Befehl (PortB)
REMA	equ	12h		;speichert Remanenz-Zustand:
;	1	"entlaust", keine Remanenz (Start mit 90°)
;	2	Remanenz positiv (Start mit 130° bzw. je nach DIL-Schalter)
;	3	Remanenz negativ (wie 2, jedoch andere Halbwelle abwarten)
;	sonst	Remanenz unbekannt (Softstart)
;REMA wird im EEPROM-Speicher (Speicherzelle 0) mitgeführt
X	equ	13h		;Hilfszelle für CheckPortChange
X1	equ	14h		;weiterer Hilfsspeicher
STARTP	equ	15h		;speichert (angelernten) Ideal-Startwinkel
;STARTP wird im EEPROM-Speicher (Speicherzelle 1) mitgeführt
PHI	equ	16h		;letzte gemessene Strom-Phase
PHASE0	equ	17h		;Kopie von PHASE für späte Zündung (>5ms)

;*********************
;** Programm im ROM **
;*********************
	org	0
	goto	start
	dw	'm','m','e'
	org	4
	retfie
;keine Interrupt-Routine

;====================
;== Unterprogramme ==
;====================
CheckTime
;Überprüft anhand des Timers, ob 11ms abgelaufen sind; wenn ja, wird das
;Label TIMEOUT angesprungen. Da der PIC-Stack zirkular ist, läuft nichts über.
	movlw	TIMEOVER
	subwf	TMR0,W		;Ist der Zählerstand zu klein?->keine Null!
	SKPC			; (W:=[Tmr0]-TIMEOVER)
	return			;okay
	goto	TIMEOUT

wait0	;eine "späte Zündung" anhand von PHASE0 ausführen
	movlw	1<<ZERO_U
	call	CheckPortChange
	btfsc	X,ZERO_U	;Geändert?
	goto	illegal_zerocross
	movfw	PHASE0
	subwf	TMR0,W
	JNC	wait0
	bcf	PORTA,TRIAC	;Triac einschalten
	clrf	PHASE0
	return

illegal_zerocross:
	xorwf	LASTIN,f	;zurücknehmen, damit es irgendwie weitergeht
	return			;Triac NICHT zünden

CheckPortChange		;Testet auf Änderung von PortB mit Bitmaske W
	;PA: W und X enthält geänderte Bits
	movwf	X		;Bits retten
	movfw	PORTB		;Port lesen
	xorwf	LASTIN,w	;Unterschiede erfassen
	andwf	X,w		;uninteressante Bits nullsetzen
	xorwf	LASTIN,f	;interessanten Teil der Änderungen speichern
	movwf	X		;Kopie nach X
	return

SavePhi			;einfach TMR0 nach PHI kopieren
	movfw	TMR0
	movwf	PHI
	return

EineZuendung
	tstf	PHASE0		;Späte Zündung?
	SKPZ
	call	wait0		;Späte Zündung jetzt "nachholen"
 ifdef SIMULATE
	goto	iszero		;Nicht erst auf Nulldurchgang warten
 endif
waitx:	;warten auf Nulldurchgang U, Mitschneiden von Nulldurchgang I
	call	CheckTime	;Zeitüberschreitung (Timeout) überwachen
	movlw	(1<<ZERO_I)+(1<<ZERO_U)
	call	CheckPortChange	;Pegelwechsel erfassen
	btfsc	X,ZERO_I	;Nulldurchgang I?
	call	SavePhi		;wenn ja: Phi speichern
	btfss	X,ZERO_U	;Nulldurchgang U?
	goto	waitx		;wenn nein, noch eine Runde warten
iszero:
	clrf	TMR0		;Zähler starten
	movfw	PHASE		;Null?
 ifdef SIMULATE
	movwf	TMR0		;Nicht erst auf Timer warten
 endif
	SKPZ			;wenn Null, Triac nicht erst ausschalten
	bsf	PORTA,TRIAC	;Triac jetzt ausschalten
	sublw	PHASE180-1	;Phasenwinkel >180°? (W:=(PHASE180-1)-W)
	SKPC
	return			;ja, Triac bleibt aus
	movfw	PHASE
	sublw	PHASE180/2	;Phasenwinkel >90°?
	SKPC
	goto	setlatestart	;ja, späte Zündung (jetzt nicht warten)
wait:	movfw	PHASE
	subwf	TMR0,W
	JNC	wait
	bcf	PORTA,TRIAC	;Triac einschalten
	return
setlatestart:
	movfw	PHASE
	movwf	PHASE0
	return

NextEERead:		;nächste EEPROM-Zelle lesen
	incf	EEADR,f
EERead:			;EEPROM lesen (lästige Bankumschaltung)
	BANKSEL	80h
	bsf	EECON1,RD	;Lesen auslösen
eerw:	btfsc	EECON1,RD
	goto	eerw
	BANKSEL	0
	return

ClearREMA:
	clrf	REMA	
WriteEEPROM:
; Diese Routine vergleicht den EEPROM- mit dem RAM-Inhalt.
; Sind diese verschieden, wird die Speicherzelle gebrannt.
; Bei gesetztem Brenn-Bit (Bit 1, "WR") wird nichts getan
	BANKSEL	80h
	movlw	1<<WR
	andwf	EECON1,w	;Brennt noch?
	BANKSEL	0
	SKPZ
	return			;Brennt noch? -> Raus!
	clrf	EEADR		;Adresse Null: Remanenz-Code
	call	EERead
	movfw	REMA
	xorwf	EEDATA,f	;Gleich? (W bleibt)
	JNZ	burn		;ungleich - brennen!
	call	NextEERead	;Adresse Eins: Idealstartphase
	movfw	STARTP
	xorwf	EEDATA,f	;Gleich? (W bleibt)
	JNZ	burn		;ungleich - brennen!
	incf	EEADR,f	;auf 2?
	return			;gleich - nichts tun
burn:	movwf	EEDATA		;Ungleich? - Neues Datum eintragen
	BANKSEL	80h
	bsf	EECON1,WREN	;Bit 2: Schreibfreigabe
	movlw	55h
	movwf	EECON2
	movlw	0AAh
	movwf	EECON2		;Kennung zun "Brennen"
	bsf	EECON1,WR	;Brennung auslösen
	BANKSEL	0
	return

RelayOff		;Relais ausschalten und warten, VR: X1
	bsf	PORTA,RELAY
	movlw	WAITRELAY
	movwf	X1
wrelay:	call	EineZuendung	;einige Male (Nulldurchgänge) warten
	decfsz	X1,f
	goto	wrelay
	return
;===================
;== Hauptprogramm ==
;===================
start:
;* Aktion 1:
;  Triac-Steuerpin auf Ausgabe programmieren, alles andere bleibt Eingabe
	clrf	STATUS
	movlw	(1<<TRIAC)+(1<<RELAY)
	movwf	PORTA		;Ausgabepins HIGH, Triac und Relais AUS
	BANKSEL	80h
	movlw	~((1<<TRIAC)+(1<<RELAY)+(1<<TESTA))
	movwf	TRISA		;auf Ausgabe schalten, alles andere Eingabe
	movlw	0F0h
	movwf	TRISB
;* Aktion 2:
;  Timer programmieren: Vorteiler 64, Gesamtzählumfang=256*64µs=16,384ms
;  (Zähler zählt aufwärts) - wir sind noch in Bank 1
	movlw	00000101b	;bei Bit7 widersprechen sich die Bücher
	movwf	OPTION_REG
	BANKSEL	0
	clrf	TMR0
;* Aktion 3:
;  Variablen vorbelegen: Phase, LastIn, Schaltzustand
	movlw	PHASE180	;Trafo ist AUS
	movwf	PHASE
	clrf	EEADR
	call	EERead
	movfw	EEDATA
	movwf	REMA		;Remanenz des Trafokerns
	call	NextEERead
	movfw	EEDATA
	movwf	STARTP		;Startphase
	movfw	PORTB
	movwf	LASTIN
TIMEOUT:
	bsf	LASTIN,SWON	;Schalter sei AUS, Pegel HIGH
	clrf	PHASE0		;keine "späte Zündung"
	goto	nowrite	;kein "Nachbrennen" bei Stromausfall
;(Neuen Einschaltvorgang erzwingen bei Netzzuschaltung)
main_loop:
	call	WriteEEPROM	;Ggf. EEPROM an REMA angleichen
nowrite:
 ifdef DEBUG
	bsf	PORTA,TESTA	;**!**
	movfw	REMA
	xorlw	2
	SKPNZ
	bcf	PORTA,TESTA	;**!**
 endif
	call	EineZuendung	;wartet bis knapp 10ms
 ifdef DEBUG
	bcf	PORTB,2
	bcf	PORTB,3
	movfw	REMA
	xorlw	2
	SKPNZ
	bsf	PORTB,2		;Bit2=1 wenn REMA=2
	xorlw	3^2
	SKPNZ
	bsf	PORTB,3		;Bit3=1 wenn REMA=3
;sonst bleiben die beiden Ausgänge low und die Duo-LED aus
	bcf	PORTB,1
	movfw	STARTP		;Startwinkel nach W
	JZ	NO_LED		;wenn Null: ungültig
	sublw	PHASE180/2
	SKPNC			;zu groß: ebenfalls ungültig
	bsf	PORTB,1
NO_LED:
 endif
; bei Zeitüberschreitung kehrt diese Funktion nicht zurück, sondern
; springt TIMEOUT an
;Jetzt: Schalter abfragen
	movlw	(1<<SWON)+(1<<SWLEARN)
	call	CheckPortChange
	btfsc	X,SWLEARN
	call	HandleSwLearn
	btfss	X,SWON
	goto	main_loop	;wenn ON-Schalter unverändert
;hier: der Schalter wurde betätigt, aber in welche Richtung?
	btfss	LASTIN,SWON	;Schalter AUS? (LOW-Aktiv!)
	goto	switch_on	;gehe zu Einschaltroutine
;hier: der Schalter wurde gerade ausgeschaltet
;zuerst: Relais aus
	call	RelayOff
;jetzt: "hart" ausschalten
	movlw	PHASE180
	movwf	PHASE
	call	EineZuendung	;warten bis Nulldurchgang
	call	EineZuendung	;ausschalten
; falls gerade hier ein Stromausfall auftritt, bleibt die Remanenz
; unbekannt
	movlw	2		;Remanenz positiv?
	btfsc	LASTIN,ZERO_U	;Vorzeichen sind Glückssache!
	movlw	3		;Remanenz negativ
put_W_to_REMA:
	movwf	REMA		;abspeichern (lassen)
	goto	main_loop

switch_on:
;hier: der Schalter wurde gerade eingeschaltet
;jetzt: je nach REMA verschieden einschalten (intelligent)
on_intelligent:
;Strategie je nach REMA auswählen
	decfsz	REMA,f		;1->0
	goto	on_try2		;springe wenn Kern nicht entmagnetisiert
	call	ClearREMA
	movlw	PHASE180/2	;90° - dürfte gar nicht auftreten!
on_start_with_W:
	movwf	PHASE
	call	EineZuendung
on_0:				;alle weiteren mit 0°
	clrf	PHASE		;voll einschalten
	bcf	PORTA,RELAY	;und Relais zuschalten
	goto	main_loop
on_try2:
	movlw	1<<ZERO_U	;das "Vorzeichen"
	decfsz	REMA,f
	goto	on_try3
on_intelli_fast:
	xorwf	LASTIN,w	;verknüpft mit aktueller Halbwelle
	movwf	X1		;und für btfsX in den Hilfsspeicher
	movfw	STARTP		;Startwinkel nach W
	JZ	on_soft_x	;wenn Null (ohne Messung): Softstart
	sublw	PHASE180/2
	JNC	on_soft_x	;zu groß: ebenfalls Softstart
	movfw	STARTP
	btfss	X1,ZERO_U	;HIER: Glücksbit: btfsc oder btfss?
	sublw	PHASE180	;ggf. W:=PHASE180-W
	movwf	X1		;retten
	call	ClearREMA	;zuerst EEPROM "behandeln"
	movfw	X1		;laden
	goto	on_start_with_W
on_try3:
	clrw
	decfsz	REMA,f
	goto	on_soft_x	;alle anderen Zahlen: Softstart
	goto	on_intelli_fast	;mit W=0
on_soft_x:
	call	ClearREMA
on_soft:
	movlw	PHASEADD
	subwf	PHASE,f		;[Phase]:=[Phase]-PHASEADD
	JNC	on_0		;!bei Überlauf ist CY=0
	call	EineZuendung
	goto	on_soft		;nächste Runde

HandleSwLearn		;SWLearn-Taste gedrückt oder losgelassen
			;UP darf X nicht verändern!
	btfsc	LASTIN,SWLEARN	;Taste gedrückt? (LOW-aktiv!)
	return			;wenn AUS nicht messen!
	btfsc	LASTIN,SWON	;Schalter ist EIN?
	goto	ClearREMA	;AUS: Remanenz löschen
;zuerst: Relais ausschalten (sonst keine Strommessung möglich)
	call	RelayOff
	movfw	PHI
	movwf	X1
	call	EineZuendung	;noch eine Phasenmessung mehr
;jetzt: Relais wieder einschalten
	bcf	PORTA,RELAY
	movfw	PHI
	addwf	X1,f
	rrf	X1,w		;Arithmetisches Mittel aus 2 Messungen
	movwf	STARTP		;...und das ist STARTP
	return

	END